使用 VBA 以外的其它编程语言

Sub Example_Alignment()
   ' 该示例在模型空间中创建文字对象，
   ' 并且重新设置该文字字符串的对齐方式。
    
    Dim textObj As AcadText
    Dim textString As String
    Dim insertionPoint(0 To 2) As Double, alignmentPoint(0 To 2) As Double
    Dim height As Double
    Dim oldPDMODE As Integer
    Dim pointObj As AcadPoint
    
    ' 定义新的文字对象
    textString = "Hello, World."
    insertionPoint(0) = 3: insertionPoint(1) = 3: insertionPoint(2) = 0
    alignmentPoint(0) = 3: alignmentPoint(1) = 3: alignmentPoint(2) = 0
    height = 0.5
    
    ' 在模型空间中创建文字对象
    Set textObj = ThisDrawing.ModelSpace.AddText(textString, insertionPoint, height)
    
    oldPDMODE = ThisDrawing.GetVariable("PDMODE")   ' Record existing point style
    
    ' 在文字对齐点处创建一个十字标志以更好的看到对齐过程
    Set pointObj = ThisDrawing.ModelSpace.AddPoint(alignmentPoint)
    
    ThisDrawing.SetVariable "PDMODE", 2             ' 设置点样式为十字标志
        
    ThisDrawing.Application.ZoomAll
    
    ' 将文字的对齐方式设置为默认值 acAlignmentLeft 以外的其它值。
    ' 创建的点将作为对齐的参考点
    textObj.Alignment = acAlignmentRight
    
    ' 将文字的对齐到参考点处，此时文字将自动对齐到该点的右边，因为文字的对齐方式已经设置为 acAlignmentRight
    textObj.TextAlignmentPoint = alignmentPoint
    ThisDrawing.Regen acActiveViewport
    MsgBox "文字对象现在已经对齐到对齐点的右边。"
    
    ' 将文字按对齐点对中
    textObj.Alignment = acAlignmentCenter
    ThisDrawing.Regen acActiveViewport
    MsgBox "T文字对象现在已经对齐到对齐点的中心。"
    
    ' 恢复点样式
    ThisDrawing.SetVariable "PDMODE", oldPDMODE
End Sub