注册 登录
明经CAD社区 返回首页

Gu_xl的个人空间 http://www.mjtd.com/?161460 [收藏] [复制] [分享] [RSS]

日志

块内填充对象置后显示

热度 8已有 2815 次阅读2014-7-17 15:54 |个人分类:Lisp应用|系统分类:应用| 块内填充对象置后显示

块内填充对象后置显示.LSP

块内填充对象后置显示.LSP

本源代码由 Gu_xl 编写发布! 联系方式: Email: Gu_xl@sohu.com
;;块内填充对象置后显示,CAD2005以上版本适用 By Gu_xl 2014.07.17
(defun c:tt (/ en sortents dict blockdef lst Doc)
  (if (and (setq en (car (entsel "\n选择块:")))
	   (= "INSERT" (cdr (assoc 0 (setq en (entget en)))))
      )
    (progn
      (cond
	(
	 (not
	   (VL-CATCH-ALL-ERROR-P
	     (setq sortents
		    (VL-CATCH-ALL-APPLY
		      'vla-item
		      (list
			(setq dict
			       (vla-GetExtensionDictionary
				 (setq blockdef
					(vla-item
					  (vla-get-blocks
					    (setq doc
						   (vla-get-ActiveDocument
						     (vlax-get-acad-object)
						   )
					    )
					  )
					  (cdr (assoc 2 en))
					)
				 )
			       )
			)
			"ACAD_SORTENTS"
		      )
		    )
	     )
	   )
	 )
	)
	((setq sortents
		(VL-CATCH-ALL-APPLY
		  'vla-AddObject
		  (list dict "ACAD_SORTENTS" "AcDbSortentsTable")
		)
	 )
	)
      )
      (vlax-for	obj blockdef
	(if (= "AcDbHatch" (vla-get-objectname obj))
	  (setq lst (cons obj lst))
	)
      )
      (if lst
	(progn
	  (vla-MoveToBottom
	    sortents
	    (vlax-make-variant
	      (vlax-safearray-fill
		(vlax-make-safearray
		  vlax-vbobject
		  (cons 0 (1- (length lst)))
		)
		lst
	      )
	    )
	  )
	  (vla-regen doc :vlax-true)
	)
      )
    )
  )
  (princ)
)

路过

雷人
7

握手

鲜花

鸡蛋

刚表态过的朋友 (7 人)

发表评论 评论 (3 个评论)

回复 裤裆有异味 2014-7-17 16:42
沙发……
回复 风树 2014-7-17 19:31
楼上,洗澡啊
回复 勤快的猫王 2017-12-21 13:20
不错哦

facelist doodle 涂鸦板

您需要登录后才可以评论 登录 | 注册

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码,在未取得本站及作者授权的情况下,不得用于商业用途

GMT+8, 2024-3-28 20:12 , Processed in 0.317742 second(s), 17 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

返回顶部