求助：如何在下面这段画立面窗的源码中加入窗上下分隔为3档的源码（已解决）
本帖最后由 注册 于 2012-3-12 19:19 编辑(defun C:wrf_lmw( / lay os rows colu row1 row2 colu1
pt pt0 pt1 pt2 pt3 pt4 ww)
(setvar "CMDECHO" 0)
(setq lay (getvar "clayer"))
(setq os (getvar "OSMODE"))
(setvar "OSMODE" 3)
(command "color" "bylayer")
(command "layer" "m" "lmw" "c" "146" "lmw" "")
(setq rows (getint "\n窗上下分格数(1不分格)/<或2>: "));
(if (= rows nil) (setq rows 2))
(setq colu (getint "\n窗扇数<3>: "))
(if (= colu nil) (setq colu 3))
(setq row1 (getreal "\n窗高<1500>: "))
(if (= row1 nil) (setq row1 1500))
(if (= rows 2)
(progn
(setq row2 (getreal "\n窗上格高度<450>: "))
(if (= row2 nil) (setq row2 450))
)
(setq row2 0)
)
(setq colu1 (getreal "\n窗宽<1500>: "))
(if (= colu1 nil) (setq colu1 1500))
(setq pt (getpoint "\n窗左下角点: "))
(setq pt1 pt) (setq ww (/ colu1 colu)) ;数据输入
(setq pt2 (polar pt1 0 colu1)) ;
(setq pt3 (polar pt2 (* pi 0.5) row1))
(setq pt4 (polar pt1 (* pi 0.5) row1))
(command "line" pt1 pt2 pt3 pt4 pt1 "") ;外框线
(if (= rows 2)
(progn
(setq pt2 (polar pt1 (* pi 0.5) (- row1 row2)));
(setq pt3 (polar pt2 0 colu1))
(command "line" pt2 pt3 "") ;横线
)
)
(if (>= colu 2) ;
(progn
(repeat (1- colu)
(setq pt2 (polar pt1 0 ww))
(setq pt3 (polar pt2 (* pi 0.5) row1))
(command "line" pt2 pt3 "")
(setq pt1 pt2)
)
)
) ;竖线
(setq pt0 pt) ;
(repeat colu
(setq pt1 (polar pt0 (* pi 0.25) 63.6396))
(setq pt2 (polar pt1 0 (- ww 90)))
(setq pt3 (polar pt1 (* pi 0.5) (- row1 row2 90)))
(setq pt4 (polar pt2 (* pi 0.5) (- row1 row2 90)))
(command "line" pt1 pt2 pt4 pt3 pt1 "")
(setq pt0 (polar pt0 0 ww)) ;下框内框线
)
(if (= rows 2)
(progn
(setq pt0 (polar pt (* pi 0.5) (- row1 row2))) ;
(repeat colu
(setq pt1 (polar pt0 (* pi 0.25) 63.6396))
(setq pt2 (polar pt1 0 (- ww 90)))
(setq pt3 (polar pt1 (* pi 0.5) (- row2 90)))
(setq pt4 (polar pt2 (* pi 0.5) (- row2 90)))
(command "line" pt1 pt2 pt4 pt3 pt1 "")
(setq pt0 (polar pt0 0 ww)) ;上框内框线
)
)
)
(setvar "OSMODE" os)
(command "layer" "s" lay "")
(redraw)
(princ)
)
这是我网上找来的画立面窗的源码，很方便，有个不情之请，就是原来窗上下分隔只能为1或2档，如果窗比较高（比如2700高),如何将分档调整为3挡，谢谢
呜呼，雷锋哪里去哉 雷锋叔叔不会LISP
(defun C:wrf_lmw( / lay os rows colu row1 row2 colu1
pt pt0 pt1 pt2 pt3 pt4 ww)
(setvar "CMDECHO" 0)
(setq lay (getvar "clayer"))
(setq os (getvar "OSMODE"))
(setvar "OSMODE" 3)
(command "color" "bylayer")
(command "layer" "m" "lmw" "c" "146" "lmw" "")
(setq rows (getint "\n窗上下分格数(1不分格)/<或2>: "));
(if (= rows nil) (setq rows 2))
(setq colu (getint "\n窗扇数<3>: "))
(if (= colu nil) (setq colu 3))
(setq row1 (getdist "\n窗高<1500>: "))
(if (= row1 nil) (setq row1 1500))
(if (> rows 1) (progn
(setq row2 (getdist "\n窗上格高度<450>: "))
(if (= row2 nil) (setq row2 450))
)
(setq row2 1)
)
(setq colu1 (getdist "\n窗宽<1500>: "))
(if (= colu1 nil) (setq colu1 1500))
(setq pt (getpoint "\n窗左下角点: "))
(setq pt1 pt)
(setq ww (/ colu1 colu)) ;数据输入
(setq pt2 (polar pt1 0 colu1))
(setq pt3 (polar pt2 (* pi 0.5) row1))
(setq pt4 (polar pt1 (* pi 0.5) row1))
(command "line" pt1 pt2 pt3 pt4 "c") ;外框线
(setq ptt pt4 pt2 pt4)
(repeat (1- rows)
(setq pt2 (polar pt2 (/ pi -2) row2))
(setq pt3 (polar pt2 0 colu1))
(command "line" pt2 pt3 "") ;横线
)
(setq pt2 pt1)
(if (> colu 1)
(repeat (1- colu)
(setq pt2 (polar pt2 0 ww))
(setq pt3 (polar pt2 (* pi 0.5) row1))
(command "line" pt2 pt3 "")
)
) ;竖线
(setq pt0 pt)
(repeat colu
(setq pt1 (mapcar '+ pt0 '(45 45 0)))
(setq pt2 (polar pt1 0 (- ww 90)))
(setq pt3 (polar pt1 (* pi 0.5) (- row1 (* row2 (1- rows)) 90)))
(setq pt4 (polar pt2 (* pi 0.5) (- row1 (* row2 (1- rows)) 90)))
(command "line" pt1 pt2 pt4 pt3 "c")
(setq pt0 (polar pt0 0 ww)) ;下框内框线
)
(repeat (1- rows)
(setq ptt (polar ptt (/ pi -2) row2))
(setq pt0 ptt)
(repeat colu
(setq pt1 (mapcar '+ pt0 '(45 45 0)))
(setq pt2 (polar pt1 0 (- ww 90)))
(setq pt3 (polar pt1 (* pi 0.5) (- row2 90)))
(setq pt4 (polar pt2 (* pi 0.5) (- row2 90)))
(command "line" pt1 pt2 pt4 pt3 "C")
(setq pt0 (polar pt0 0 ww)) ;上框内框线
)
)
(setvar "OSMODE" os)
(command "layer" "s" lay "")
(redraw)
(princ)
)
多谢zzxxqq版主，雷锋节快乐 ZZXXQQ 发表于 2012-3-4 22:06 static/image/common/back.gif
雷锋叔叔不会LISP
如果让横线和竖线代码支掉,
让窗框的数都是45,中间也是45,因去掉了横竖线,所以不用90,该怎么改?
谢谢! 好像还是不能实现上下3段吧，
页:
[1]