自贡黄明儒 发表于 2011-10-13 16:45:49

[求助]<快速新建>启动模板文件

;;;<快速新建>启动模板文件
;;;op→文件→Template Settings→Default Template File Name for Qnew
;;;若我的模版文件为a4.dwt
(defun MyTemplate (/ DEFAULT NAME REGPATH REVISION VERSION)
(setq        regpath       "HKEY_CURRENT_USER\\Software\\Autodesk\\AutoCAD"
        revision (vl-registry-read regpath "CurVer")
        version       (vl-registry-read
                   (setq regpath (strcat regpath "\\" revision))
                   "CurVer"
               )
        default       (vl-registry-read
                   (setq regpath (strcat regpath "\\" version "\\Profiles"))
               )
        regpath       (strcat regpath "\\" default "\\General")
        default       (vl-registry-read regpath "QnewTemplate")
)
(if default
    (setq name (VL-FILENAME-BASE default))
)
(if (or (not default) (not (equal name "a4")))
    (vl-registry-write
      regpath
      "QnewTemplate"
      (FINDFILE "a4.dwt")
    )
)
(princ)
)
;;;<快速新建>启动模板文件
(MyTemplate)
;;;?打开注册表,可以看到成功改变,可当重新启动CAD后,模板文件又恢复到原来的模板文件,同时注册表中的值也恢复到原来的值,这是为什么呢?

caoyin 发表于 2011-10-13 17:11:06

(vla-put-QNewTemplateFile
(vla-get-Files(vla-get-Preferences(vlax-get-acad-object)))
"c:\\MyDWT.dwt"
)

自贡黄明儒 发表于 2011-10-13 16:49:20

本帖最后由 自贡黄明儒 于 2011-10-13 16:50 编辑

;模板路径的获得却很容易，是不是<快速新建>储藏在某个变量中？

自贡黄明儒 发表于 2011-10-14 12:46:45

caoyin 发表于 2011-10-13 17:11 static/image/common/back.gif
(vla-put-QNewTemplateFile
(vla-get-Files(vla-get-Preferences(vlax-get-acad-object)))
"c:\\MyDWT.dw ...

非常感谢，就这么简单一句就搞定了。高手就是高手！！！
页: [1]
查看完整版本: [求助]<快速新建>启动模板文件