senica 发表于 2003-2-9 13:08:00

新年好！请教各位。

本帖最后由 作者 于 2003-2-9 13:08:47 编辑

小弟有一问题请各位大侠指点：如何批量将ACAD2000的DWG文件转换为R14的DWG文件？谢谢！

thcad 发表于 2003-2-9 21:14:00

save as...

senica 发表于 2003-2-9 21:44:00

thcad，我想知道如何一次转换一批文件？

thcad 发表于 2003-2-10 12:38:00

这就难了!

R12/13/14文件批量转换的工具就有,但14/15互换的工具我还没发现!!

龙龙仔 发表于 2003-2-11 09:16:00

虽然速度慢了点,但非常实用

;;批量处理档转存别种格式                              
;;虽然速度慢了点,但非常实用                              
;;注意:转存R15以下无预览图                              
;;By LUCAS(龙龙仔)                                       
;;                                                      
;;虽配合Expresstools__(acetutil.arx)                     
;;为加速程序执行,程序将设定系统变量ACADLSPASDOC         
;;即<只载入 acad.lsp 至 AutoCAD 执行期所开启的第一个图面>
;;当然程序结束后,会还原系统变量ACADLSPASDOC               
;;                                                      
;;acR12_DXF:                AutoCAD Release12/LT2DXF (*.dxf)
;;acR13_DWG:                AutoCAD Release13/LT95 DWG (*.dwg)
;;acR13_DXF:                AutoCAD Release13/LT95 DXF (*.dxf)
;;acR14_DWG:                AutoCAD Release14/LT97 DWG (*.dwg)
;;acR14_DXF:                AutoCAD Release14/LT97 DXF (*.dxf)
;;acR15_DWG:                AutoCAD 2000 DWG (*.dwg)
;;acR15_DXF:                AutoCAD 2000 DXF (*.dxf)
;;acR15_Template:        AutoCAD 2000 Drawing Template File (*.dwt)   
;;acNative:                A synonym for the latest drawing release.   
;;                      In this release, this value equals acR15_DWG.
;;                                                                  
;;USAGE: (CH "acR14_DWG")

(arxload "acetutil.arx" NIL)
(vl-load-com)
(defun CH (MODE / HOLDECHO APP DWGNAME PREFIX_DWG NN QQ HOLDLSP WW LL)
(setq HOLDECHO (getvar "cmdecho"))
(setvar "cmdecho" 0)
(setq        PREFIX_DWG
       (strcat
           (strcase (acet-ui-pickdir
                      "选择目录"
                      (vl-string-right-trim "\\" (getvar "dwgprefix"))
                      "移除未使用之具名参考"
                  )
           )
           "\\"
       )
)
(setq HOLDLSP (getvar "ACADLSPASDOC"))
(setvar "acadlspasdoc" 0)
(setq QQ (vl-directory-files PREFIX_DWG "*.DWG"))
(setq NN 0)
(if (/= QQ NIL)
    (progn
      (setq APP (vlax-get-acad-object))
      (repeat (length QQ)
        (setq DWGNAME (strcase (strcat PREFIX_DWG (nth NN QQ))))
        (setq WW (vla-open (vla-get-documents APP) DWGNAME))
        (setq LL (strlen MODE))
        (cond
          ((or (equal (strcase (substr MODE (- LL 2) 3)) "DXF")
             (equal (strcase (substr MODE (- LL 7) 8)) "TEMPLATE")
           )
           (vla-saveas
             WW
             (vl-string-right-trim ".DWG" (strcase DWGNAME))
             (eval (read MODE))
           )
          )
          (t
           (vla-saveas WW DWGNAME (eval (read MODE)))
          )
        )
        (prompt (strcat "\n" DWGNAME " <PURGE完成>!!!"))
        (vla-close WW :vlax-false)
        (setq NN (1+ NN))
      )
      (vlax-release-object WW)
      (vlax-release-object APP)
    )
    (prompt "\n所选目录中未有任何图档!!!")
)
(setvar "acadlspasdoc" HOLDLSP)
(setvar "cmdecho" HOLDECHO)
(princ)
)
(princ)

秋枫 发表于 2003-2-11 10:13:00

使用autocad migration assistant中的batch convert即可。

页: [1]
查看完整版本: 新年好！请教各位。