社区 › 源码共享 › 【MakeHatch4PTLst】Entmake填充

kucha007 发表于 2025-3-29 14:57:27

【MakeHatch4PTLst】Entmake填充

本帖最后由 kucha007 于 2025-3-29 15:09 编辑

来自此贴，多段线带凸度也可以填充。我做了一些优化
主要是可以生成双向的自定义填充，也支持UCS
如果需要返回图元名称就把entmake改为entmakeX


;点表生成填充@ElpanovEvgeniy
(defun T:MakeHatch4PTLst (WCSLst PatNam PatLay PatCol PatSca)
    (entmake
      (apply
      'append
      (list
          (list
            (cons 0 "HATCH")
            (cons 100 "AcDbEntity")
            (cons 410 "Model")
            (cons 100 "AcDbHatch")
            (cons 10 '(0.0 0.0 0.0))
            (cons 210 (trans '(0 0 1) 1 0 T ))
            (if (wcmatch PatNam "_U*")
                (cons 2 "_USER")
                (cons 2 PatNam)
            )
            (cons 8 (if PatLay PatLay "0"))
            (cons 62 (if (and PatCol (< 0 (abs PatCol) 256)) PatCol 7))
            (cons 70 0);实体填充？
            (cons 71 0)
            (cons 91 (length WCSLst))
          )
          (apply
            'append
            (mapcar
            '(lambda (XX)
                (apply
                  'append
                  (list
                  (list (cons 92 7) (cons 72 1) (cons 73 1) (cons 93 (/ (length XX) 2)))
                  XX
                  (list (cons 97 0))
                  )
                )
            )
            WCSLst
            )
          )
          (list
            (cons 75 0)
            (cons 76 1)
            (cons 52 (- 0.0 (angle '(0 0 0) (trans (getvar "UCSXDIR") 0 (trans '(0 0 1) 1 0 T )))))
            (cons 41 PatSca)
            (if (and
                  (wcmatch PatNam "_U*")
                  (wcmatch PatNam "*-D")
                )
                (cons 77 1);双向
                (cons 77 0)
            )
            (cons 78 1)
            (cons 53 (- 0.0 (angle '(0 0 0) (trans (getvar "UCSXDIR") 0 (trans '(0 0 1) 1 0 T )))))
            (cons 43 0.)
            (cons 44 0.)
            (cons 45 1.)
            (cons 46 1.)
            (cons 79 0)
            (cons 47 1.)
            (cons 98 2)
            (cons 10 '(0.0 0.0 0.0))
            (cons 10 '(0.0 0.0 0.0))
            (cons 451 0)
            (cons 460 0.0)
            (cons 461 0.0)
            (cons 452 1)
            (cons 462 1.0)
            (cons 453 2)
            (cons 463 0.0)
            (cons 463 1.0)
            (cons 470 "LINEAR")
          )
      )
      )
    )
)

kucha007 发表于 前天 13:47

自贡黄明儒 发表于 2025-12-5 13:09
(T:MakeHatch4PTLst (list(list -500 0)(list 500 0)(list 500 -2000)(list -500 -2800)) "GRAVEL""0" 3...

补个函数你看一下啦：

(defun C:TT (/ CreateHatchList SS i en HLst)
(defun CreateHatchList (en / i j PLst found)
    (foreach i (entget en)
      (if (= 10 (car i))
      (progn
          (setq PLst (cons i PLst))
          (setq found nil
                j   (member i (entget en))
          )
          (while (and (not found) (< 0 (length j)))
            (if (= 42 (car (car j)))
            (setq PLst (cons (car j) PLst)
                  found t
            )
            )
            (setq j (cdr j))
          )
      )
      )
    )
    (reverse PLst)
)
(setq SS nil)
(while (setq SS (ssget '((0 . "LWPOLYLINE"))))
      (repeat (setq i (sslength SS))
          (setq en (ssname SS (setq i (1- i))))
          (if (setq tmp (CreateHatchList en))
            (setq HLst (cons tmp HLst))
          )
      )
      (setq HLst (reverse HLst))
      (T:MakeHatch4PTLst HLst "ANSI31" "0" 1 10)
)
(princ)
);defun

loveu515 发表于 2025-3-29 19:15:52

感谢分享，收藏备用

muai2010 发表于 2025-3-29 22:27:11

感谢分享..

moranyuyan 发表于 2025-3-30 18:42:58

谢谢分享

尘缘一生 发表于 2025-3-30 22:46:27

410组码改下子


[*](cons 410 (getvar "ctab"))

kucha007 发表于 2025-3-30 23:42:35

尘缘一生 发表于 2025-3-30 22:46
410组码改下子




本来想改，测试改不改都能生成，就没改了

czb203 发表于 2025-5-29 23:37:32

WCSLst 点集样式有没要求哦，搞了好久都不行

自贡黄明儒 发表于 前天 13:09

(T:MakeHatch4PTLst (list(list -500 0)(list 500 0)(list 500 -2000)(list -500 -2800)) "GRAVEL""0" 3 1)运行有问题，错在什么地方呀？

查看完整版本: 【MakeHatch4PTLst】Entmake填充